Πως μπορώ να βαλω χρωμα στον vi?

[paopipis]

Συγκεκριμενα πώς μπορώ να κανω τον vi να εχει text highlighting?

Exω SUSE 9.3 και θελω να αναγνωρίζει την C και να βαζει χρωματα στις δεσμευμενες λεξεις.

Προσοχη δεν θελω να δουλευω με αλλον editor θελω να το κανω αυτο στον vi του GNOME TERMINAL. :-D

[NullScan]

Δές εδώ

Έχει ένα πολύ καλό howto. Γενικώς θα σου πώ ότι γίνεται με κάποια scripts που βάζεις στο home σου μέσα στο directory .vimrc

[paopipis]

Ρε μάγκες, δεν μπορώ να κανω αυτο που λενε οι οδηγιες που με παρεπεμψε ο φιλος ανωτερω.

Οι οδηγιες ειναι οι εξης:

>To enable the syntax color highlighting you should copy the vimrc file to your home directory. This will also put the "Syntax" Menu with gvim command. You can click on Syntax Menu and select appropriate languages like C++, Perl, Java, SQL, ESQL etc..

cd $HOME
cp /usr/doc/vim-common-5.3/gvimrc_example  ~/.gvimrc
cp /usr/doc/vim-common-5.3/vimrc_example  ~/.vimrc

Comment lines in .vimrc begin with double-quotes ("). You can customize vim by editing the file $HOME/.vimrc and put the following lines -

"set guifont=9x15bold
set guifont=8x13bold
"set guifont=7x14bold
"set guifont=7x13bold

It is very strongly recommended that you set the tabstop to 4 and shiftwidth to 4. The tabstop is number spaces TAB will put while editing with gvim. The shiftwidth is the number spaces the lines will be shifted with ">>" or "<<" vi commands. Refer to Vi tutorials Vim Tutorial for more details. To set the tabstop and shiftwidth -

set tabstop=4
set shiftwidth=4
set nowrapscan
set ignorecase

 

Μου λεει οτι δεν βρισκει τον φακελο /usr/doc/vim-common-5.3/gvimrc_example

Οταν πληκτρολογω την εντολη στο GNOME TERMINAL.

Ας βοηθησει καποιος γνωστης γιατι εγω ειμαι αρχάριος....

στο $ τι να βαλω? root aς πουμε ή peirama (δηλαδή το logname που έχω)?

Το εχει καταφερει κανεις απο εσας??

[Theoxaris]

Καθώς θα βρίσκεσαι στο home directory σου κάνε τα εξής βηματάκια:

 

>
vim .vimrc

μέσα στο αρχείο αυτό γράψε τις εντολές:

 

>
syntax enable
colorscheme darkblue
set autoindent

 

αν θέλεις άλλο colorscheme καθώς θα είσαι στο vi δώσε την εντολή

 

>
:colorscheme <tab>

 

και θα σου βγάλει τα διαθέσιμα colorschemes. Δοκίμασέ τα και αντί για darkblue βάλε αυτό που θα σου αρέσει περισσότερο.

[apoikos]

Μετέφερα τα άσχετα posts εδώ: http://www.insomnia.gr/vb3/showthread.php?t=139472 ;-)

[paopipis]

Φίλε Theoxaris σε ευχαριστώ για την λύση που μου έδωσες!!

Τελικά τώρα τα βλέπω ολα εγχρωμα στον vi μου και η C καθώς και οι αλλες γλωσσες προγραμματισμου που ασχολούμαι ειναι πια πιο <<ανθρώπινες>>!!!!

Επιτελους ρε παιδιά ξέρετε πόσες φορές είχα errors μόνο και μόνο επείδη είχα ξεχάσει να κλεισω τα " (κοινώς αυτάκια μην ακούσω πάλι διαφωνίες για το πως λέγονται κανονικά γιατι θα αφρίσω!!!! )

[Theoxaris]

Φίλε Theoxaris σε ευχαριστώ για την λύση που μου έδωσες!!

Τελικά τώρα τα βλέπω ολα εγχρωμα στον vi μου και η C καθώς και οι αλλες γλωσσες προγραμματισμου που ασχολούμαι ειναι πια πιο <<ανθρώπινες>>!!!!

Επιτελους ρε παιδιά ξέρετε πόσες φορές είχα errors μόνο και μόνο επείδη είχα ξεχάσει να κλεισω τα " (κοινώς αυτάκια μην ακούσω πάλι διαφωνίες για το πως λέγονται κανονικά γιατι θα αφρίσω!!!! )

 

Anytime:wink:

[aldo]

An se endiaferoun merika akoma kaloudia, edw einai to vimrc pou xrhsimopoiw (kgw kapou sto internet to exw brei kai exw kanei merikes allages)

 

>
""""""""""""""""""""""""""""""""""""""""""
" GUI options, and colorscheme selection "
""""""""""""""""""""""""""""""""""""""""""

set guioptions-=L
set guioptions-=l
set guioptions-=r
set guioptions-=R
set mouse=a
map <F12> :browse confirm e<CR>
color delek


"""""""""""""
" Functions "
"""""""""""""

" Add timestamp to rc files
fun! <SID>UpdateRcHeader()
   let l:c=col(".")
   let l:l=line(".")
   1,10s-\(Most recent update:\).*-\="Most recent update: ".strftime("%c")-
   call cursor(l:l, l:c)
endfun

" Set up the status line
fun! <SID>SetStatusLine()
   let l:s1="%-3.3n\\ %f\\ %h%m%r%w"
   let l:s2="[%{strlen(&filetype)?&filetype:'?'},%{&encoding},%{&fileformat}]"
   let l:s3="%=\\ 0x%-8B\\ \\ %-14.(%l,%c%V%)\\ %<%P"
   execute "set statusline=" . l:s1 . l:s2 . l:s3
endfun


""""""""""""
" Settings "
""""""""""""

" Encoding
if ($TERM == "rxvt-unicode") && (&termencoding == "")
   set termencoding=utf-8
endif
set encoding=utf-8

" Basic options
set nocompatible
set history=50
set viminfo='1000,f1,:1000,/1000
set shortmess+=aI
set showmode
set showcmd
set modeline
set wildmenu

" Indent, tab, and wrap settings
set noexpandtab
set shiftwidth=4
set softtabstop=4
set tabstop=4
set shiftround
set autoindent
set smartindent
set textwidth=72
set nowrap
set formatoptions+=nl
set whichwrap=h,l,~,[,]
set backspace=eol,start,indent

" Search options
set nohlsearch
set ignorecase
set incsearch
set gdefault
set showmatch

" Set a toggle for pasting input
set pastetoggle=<F10>

" Set special characters
set listchars+=tab:»·,trail:·,extends:~

" Set bracket matching and comment formats
set matchpairs+=<:>
set comments-=s1:/*,mb:*,ex:*/
set comments+=s:/*,mb:**,ex:*/
set comments+=fb:*
set comments+=b:\"
set comments+=n::

" Use less space for line numbering if possible
if v:version >= 700
   try
       setlocal numberwidth=3
   catch
   endtry
endif

" Turn line numbers on by default
set number

" Use css for generated html files
let html_use_css=1

" Setup a funky statusline
set laststatus=2
call <SID>SetStatusLine()

" Set taglist plugin options
let Tlist_Use_Right_Window = 1
let Tlist_Exit_OnlyWindow = 1
let Tlist_Enable_Fold_Column = 0
let Tlist_Compact_Format = 1
let Tlist_File_Fold_Auto_Close = 0
let Tlist_Inc_Winwidth = 1

" Set minibufxpl plugin options
let g:miniBufExplModSelTarget = 1
let g:miniBufExplModSelTarget = 1

" Basic abbreviations
iab teh the
iab DATE <C-R>=strftime("%B %d, %Y (%A, %H:%Mh)")<CR>

" Enable filetype detection
filetype on
filetype plugin on
filetype indent on


""""""""""""""""
" Autocommands "
""""""""""""""""

" Clear autocmds - starts from a clean slate
autocmd!

" Fix filetype detection
au BufNewFile,BufRead .torsmorc* set filetype=rc
au BufNewFile,BufRead *.inc set filetype=php
au BufNewFile,BufRead *.sys set filetype=php
au BufNewFile,BufRead grub.conf set filetype=grub

" C file specific options
au FileType c,cpp set cindent
au FileType c,cpp set formatoptions+=ro
au FileType c,cpp set makeprg=gcc\ -Wall\ -O2\ -o\ %<\ %

" HTML abbreviations
au FileType html,xhtml,php,eruby imap bbb <br />
au FileType html,xhtml,php,eruby imap aaa <a href=""><left><left>
au FileType html,xhtml,php,eruby imap iii <img src="" /><left><left><left><left>
au FileType html,xhtml,php,eruby imap ddd <div class=""><left><left>

" Compile and run keymappings
au FileType c,cpp map <F5> :!./%:r<CR>
au FileType sh,php,perl,python,ruby map <F5> :!./%<CR>
au FileType c,cpp map <F6> :make<CR>
au FileType php map <F6> :!php &<CR>
au FileType python map <F6> :!python %<CR>
au FileType perl map <F6> :!perl %<CR>
au FileType ruby map <F6> :!ruby %<CR>
au FileType html,xhtml map <F5> :!firefox %<CR>

" MS Word document reading
au BufReadPre *.doc set ro
au BufReadPre *.doc set hlsearch!
au BufReadPost *.doc %!antiword "%"

" Update header in some files before saving
au BufWritePre *vimrc  :call <SID>UpdateRcHeader()
au BufWritePre *bashrc :call <SID>UpdateRcHeader()
au BufWritePre /etc/profile :call <SID>UpdateRcHeader()
au BufWritePre *Xdefaults :call <SID>UpdateRcHeader()
au BufWritePre *muttrc :call <SID>UpdateRcHeader()


"""""""""""""""
" Keymappings "
"""""""""""""""

" Easy help
map! <F1> <C-C><F1>
vmap <F1> <C-C><F1>
omap <F1> <C-C><F1>
nnoremap <F1> :help<Space>
map <F7> :!python -c 'help()'<left><left>

" Show nonprinting characters
map <F2> :set list!<CR>
inoremap <F2> <ESC>:set list!<CR>a

" Toggle between windows
nnoremap <F3> <C-W>W
nnoremap <F4> <C-W>w

" Toggle taglist script
map <F8> :Tlist<CR>

" Toggle line numbers
map <F9> :set number!<CR>

" Toggle dark/light default colour theme for shitty terms
map <F11> :let &background = ( &background == "dark" ? "light" : "dark" )<CR>

" Swap around between buffers
nnoremap <C-N> :bn<CR>
nnoremap <C-I> :bn<CR>
nnoremap <C-P> :bp<CR>

" Convert to html
nnoremap <C-L> :runtime<Space>syntax/2html.vim<CR>

" Fast quit
map q :q<CR>
map Q :qa<CR>

" Cursor keys suck. Use ctrl with home keys to move in insert mode.
imap <C-h> <Left>
imap <C-j> <Down>
imap <C-k> <Up>
imap <C-l> <Right>

" Use o in insert mode
imap <C-O> <end><cr>


""""""""""""""""""""""""""""
" Enable syntax hilighting "
""""""""""""""""""""""""""""

syntax on

 

Kantto copy paste se kainourgio .vimrc