[INFO] ARCH Linux: Απόψεις, Ερωτήσεις, Σχόλια

jim_p · 21 Ιανουαρίου 2013

Ωρα για την καμμενη ερωτηση της ημερας.

Μια φορα και ενα καιρο, πριν 5 χρονια σχεδον που ξεκινησα με debian, για να κρυβεται η αντιαισθητικη μαυριλα με τα γραμματα που κατεβαινουν οσο φορτωνει το λειτουργικο, υπηρχε το fbsplash και ενα αλλο (usplash νομιζω). Απλα κανανε χρηση του framebuffer και δειχνανε μια εικονα αντι για τη μαυριλα.

Σημερα, εχουμε το plymouth και τα animations του, το οποιο θελει ανοιχτο το kms και ανοιχτο driver. Σε αντιθετη περιπτωση, βγαζει μια απλη και τραγικη loading bar σαν αυτη των windows 2000 (εικονα).

Τιποτε αλλο υπαρχει?

tritonas00 · 21 Ιανουαρίου 2013

Για ριχτε μια ματια αν ειναι να τα ανεβασω

# Contributor: martinoff
# Maintainer: tritonas00 <[email protected]>
pkgname=star-cli-git
pkgver=20130121
pkgrel=1
pkgdesc='backup and restore your system with tar'
arch=('any')
license=('GPL')
depends=('git'  'grub-bios' 'wget')
optdepends=( 'syslinux' 'os-prober')
url="https://github.com/tritonas00/system-tar-and-restore"
source=('readme.install')
md5sums=('84723e8d033a731e29795692d509a173')
install=readme.install
_gitname='system-tar-and-restore'
_gitroot='git://github.com/tritonas00/system-tar-and-restore.git'
_commit='b04bcdab4f928a45aa386175f4d745e60be49503'

build() {
if [ -d ${srcdir}/${_gitname}/.git ] ; then
(
cd ${srcdir}/${_gitname} && \
git checkout master && \
git pull origin master
)
msg "The local files are updated."
else
( git clone ${_gitroot} ${_gitname} )
fi
msg "GIT checkout done or server timeout"
cd ${_gitname}
# when commit is set, check that out
[[ "${_commit}" ]] && git checkout "${_commit}"
if [ "${_gitphash}" == $(git show | grep -m 1 commit | sed 's/commit //') ]; then
msg "Git hash is the same as previous build"
return 1
fi
msg "creating build directory"
cd ${srcdir}
[ -d ${_gitname}-build ] && rm -rf ${_gitname}-build
cp -a ${_gitname} ${_gitname}-build
}
package() {
cd "$srcdir/$_gitname"
install -Dm755 backup "$pkgdir/usr/bin/backup-cli"
install -Dm755 restore "$pkgdir/usr/bin/restore-cli"
}

# Contributor: martinoff
# Maintainer: tritonas00 <[email protected]>
pkgname=star-dialog-git
pkgver=20130121
pkgrel=1
pkgdesc='backup and restore your system with tar'
arch=('any')
license=('GPL')
depends=('git'  'grub-bios' 'dialog' 'wget')
optdepends=( 'syslinux' 'os-prober')
url="https://github.com/tritonas00/system-tar-and-restore/tree/dialog"
source=('readme.install')
md5sums=('262a170b500dcc914e2e67c2f89db8ba')
install=readme.install
_gitname='system-tar-and-restore'
_gitroot='git://github.com/tritonas00/system-tar-and-restore.git'
_commit='b3d55eff7bd8493bac9fdea84e4aab8d587e1613'

build() {
if [ -d ${srcdir}/${_gitname}/.git ] ; then
(
cd ${srcdir}/${_gitname} && \
git checkout dialog && \
git pull origin dialog
)
msg "The local files are updated."
else
( git clone ${_gitroot} ${_gitname} )
fi
msg "GIT checkout done or server timeout"
cd ${_gitname}
# when commit is set, check that out
[[ "${_commit}" ]] && git checkout "${_commit}"
if [ "${_gitphash}" == $(git show | grep -m 1 commit | sed 's/commit //') ]; then
msg "Git hash is the same as previous build"
return 1
fi
msg "creating build directory"
cd ${srcdir}
[ -d ${_gitname}-build ] && rm -rf ${_gitname}-build
cp -a ${_gitname} ${_gitname}-build
}
package() {
cd "$srcdir/$_gitname"
install -Dm755 backup "$pkgdir/usr/bin/backup-dialog"
install -Dm755 restore "$pkgdir/usr/bin/restore-dialog"
}

pmav99 · 21 Ιανουαρίου 2013

Ονομάζεις το πακέτο *-git που δηλώνει ότι είναι devel πακέτο, δηλαδή ότι κάθε φορά που το κτίζεις θα τραβάει την τελευταία εκδοση από το git repo. Έτσι όπως το έχεις όμως δεν τραβάει την τελευταία έκδοση αλλά ένα συγκεκριμένο commit. Σπας δηλαδή τους κανόνες του packaging guidelines (πρώτο bullet) Επίσης, αν θες να το κάνεις έτσι, τότε δεν υπάρχει λόγος να γίνεται όλη αυτή η ιστορία με το cloning του repo ή τον έλεγχο αν το local repo είναι updated. Το βάζεις να κατεβάζει κατευθείαν το αρχείο που θες. Πχ

https://github.com/tritonas00/system-tar-and-restore/blob/daab5939ed6b46f1d7507a0ed8d3e931bb8124cd/backup

Εναλλακτικά ακολουθείς την στάνταρ πρακτική και δημιουργείς ένα *.tar.gz και χρησιμοποιείς κανονικά version numbers. Ο κόπος είναι ελάχιστα περισσότερος και θα διευκολύνεις και το packaging σε άλλες διανομές.

edit

Τώρα βλέπω ότι μόλις έρθει ο pacman 4.1 δε θα χρειάζεται πια η ιστορία με το cloning των repo στα devel πακέτα. Interesting (4o bullet)

martinoff · 21 Ιανουαρίου 2013

να βγάλεις το contributor πρώτον

δεύτερο σε μένα είναι οκ και τα δυο

τρίτον κανε αυτό που λέει ο pmav αν έχεις φιλοδοξίες να μπει community να δώσουμε vote ;p

τέταρτων σκέψου αν όντος θες το readme που ο markelos είπε όχι

πέμπτο πρέπει να φτιάξεις και deb rpm (deb μπορώ rpm δεν έχω ιδέα)

pmav99 · 21 Ιανουαρίου 2013

@tritonas

Θα συμφωνήσω με τον martinoff και μάλιστα θα το πάω παρακάτω. Βγάλε τον από contributor και βάλε τον maintainer! Να μάθει να μιλάει άλλη φορά

tritonas00 · 21 Ιανουαρίου 2013

Καλα, αυριο θα το κανω με απλο tarball.

Το readme ελεγα να το εχω για να λεει στον χρηστη τα ονοματα των scripts ( backup-cli restore-cli ή backup-dialog restore-dialog )

ισα ισα να μην ψαχνει μεσα στο πακετο τι εκτελεσιμα εβαλε.

ξερω γω...

mphxths · 21 Ιανουαρίου 2013

αυτο ειναι update οχι μαλακιες.. απο 3.6.11 σε 3.7.3 (ο κερνελ).....

pmav99 · 21 Ιανουαρίου 2013

μπορείς να κάνεις και man page αν θες.

martinoff · 21 Ιανουαρίου 2013



# Maintainer: tritonas00 <[email protected]>
pkgname=star-cli-git
pkgver=11-2 (δεν βαζουμε ενα γιατι ειναι alpha )
pkgrel=1
pkgdesc='backup and restore your system'
arch=('any')
license=('GPL')
depends=('grub-bios' 'dialog' 'wget')
optdepends=('sudo' 'syslinux' 'os-prober')
url="https://github.com/tritonas00/system-tar-and-restore"
source=("blabla")
sha256sums=('123456789123456789')
install=readme.install

package() {
cd "$srcdir/$pkgver"
install -Dm755 backup "$pkgdir/usr/bin/backup-cli"
install -Dm755 restore "$pkgdir/usr/bin/restore-cli"
}

δεν το δοκιμασα

tritonas00 · 22 Ιανουαρίου 2013

Tωρα νταξει ειναι ? Σπαμε κανενα κανονα απο τις γραφες?

# Maintainer: tritonas00 <[email protected]>
pkgname=system-tar-and-restore
pkgver=2.0
pkgrel=1
pkgdesc='Backup and Restore your system using tar'
arch=('any')
license=('GPL')
depends=('grub-bios' 'dialog' 'wget')
optdepends=('syslinux' 'os-prober')
url="https://github.com/tritonas00/system-tar-and-restore"
source=("http://system-tar-and-restore.googlecode.com/files/$pkgname-$pkgver.tar.gz"
        "readme.install")

md5sums=('21dfc84cef797c8b0743c711d29771c4'
         'f2617c1b1d300d2d467269d6891da3a5')

install=readme.install

package() {
cd "$srcdir"
install -Dm755 backup-cli "$pkgdir/usr/bin/backup-cli"
install -Dm755 restore-cli "$pkgdir/usr/bin/restore-cli"
install -Dm755 backup-dialog "$pkgdir/usr/bin/backup-dialog"
install -Dm755 restore-dialog "$pkgdir/usr/bin/restore-dialog"
}

readme.install

post_install() {
echo '--------------------------------------------------------------------------'
echo 'README'
echo 'https://github.com/tritonas00/system-tar-and-restore/blob/master/README.md'
echo '--------------------------------------------------------------------------'
echo 'QUICK INSTRUCTIONS'
echo
echo 'BACKUP'
echo 'Run as root: backup-cli or backup-dialog'
echo
echo 'RESTORE'
echo 'Run as root: restore-cli or restore-dialog'
echo '--------------------------------------------------------------------------'
}

Eνα πακετακι ολα μεσα, μην τα μπλεκουμε πολυ.

mask2011 · 22 Ιανουαρίου 2013

Εγώ πάντως θέλω πολύ να σε δω να φτιάχνεις rpm και μετά να σε κυνηγάει ο τράγος...

pmav99 · 22 Ιανουαρίου 2013

Έτσι είναι cool. Iδανικά θα μπορούσες να έχεις 2 πακέτα, ένα για το cli και ένα για το dialog. To πακέτο του dialog θα έμπαινε σαν optional dependency του cli, ενώ το cli σαν κανονικό dependency του dialog. Δηλαδή θα ήταν κάπως έτσι:

# star-cli
depends=('grub-bios' 'wget')
optdepends=('syslinux' 'os-prober' 'star-cli')

# star-dialog
depends=('star-cli' 'dialog')
optdepends=()

Νομίζω ότι έχει ξαναπροταθεί στο άλλο thread, αλλά μήπως θα ήταν πιο user-friendly να υπάρχει ένα script που να καλεί τα άλλα δύο? Να ρωτάει δηλαδή αν θέλουμε backup ή restore ή/και να τσεκάρει αν υπάρχει και το dialog και, σε περίπτωση που υπάρχει, να ρωτάει αν θέλουμε cli ή dialog? Με αυτόν τον τρόπο μειώνεται το namespace pollution του /usr/bin/.

Επεξ/σία 22 Ιανουαρίου 2013 από pmav99

tritonas00 · 22 Ιανουαρίου 2013

Τα dialog scripts, δεν καλουν το cli. Ειναι ξαναγραμμενα - αυτονομα.

Η δημιουργια τριτου script που να καλει αναλογα ειναι καλη ιδεα. Θα το κοιταξω.

mandos · 22 Ιανουαρίου 2013

https://bugs.archlinux.org/task/33513

μπαίνω σε bughunting mode σιγά σιγά σε ότι αφορά τα crashes... αυτό δεν είναι ποτέ καλό... θα χρειαστώ reformart μετά από αυτό

υγ να σας φτιάξω τη διάθεση:

με ρωτάει η κοπελιά (έχει arch): τι είναι το terminal?

εγώ: εκείνο το μαύρο παράθυρο που έχω συνέχεια ανοιχτό

εκείνη: α, το pacman δηλαδή?

δεν είχα απάντηση....

tritonas00 · 22 Ιανουαρίου 2013

Ετοιμο το script, ρωταει τι θελουμε - backup ή restore και αν βρεθει στο συστημα ο dialog, τοτε τρεχει τα dialog scripts αλλιως τα cli.

O dialog μπηκε σαν optional. Επισης αφου υπαρχει το star, τα υπολοιπα ειναι καλο να ειναι στο /usr/bin ή να πανε καπου αλλου ?

# Maintainer: tritonas00 <[email protected]>
pkgname=system-tar-and-restore
pkgver=2.0
pkgrel=1
pkgdesc='Backup and Restore your system using tar'
arch=('any')
license=('GPL')
depends=('grub-bios' 'wget')
optdepends=('dialog' 'syslinux' 'os-prober')
url="https://github.com/tritonas00/system-tar-and-restore"
source=("http://system-tar-and-restore.googlecode.com/files/$pkgname-$pkgver.tar.gz"
                 "readme.install")

md5sums=('a4daa8db2e15ee7840ba34ec78e9ade1'
                       '3d66cebc9dfdc05a82d22a29ba8cd29e')

install=readme.install

package() {
cd "$srcdir"
install -Dm755 backup-cli "$pkgdir/usr/bin/backup-cli"
install -Dm755 restore-cli "$pkgdir/usr/bin/restore-cli"
install -Dm755 backup-dialog "$pkgdir/usr/bin/backup-dialog"
install -Dm755 restore-dialog "$pkgdir/usr/bin/restore-dialog"
install -Dm755 star "$pkgdir/usr/bin/star"
}

readme.install

post_install() {
echo '--------------------------------------------------------------------------'
echo 'README'
echo 'https://github.com/tritonas00/system-tar-and-restore/blob/master/README.md'
echo '--------------------------------------------------------------------------'
echo 'QUICK INSTRUCTIONS'
echo
echo 'Run star as root to begin'
echo '--------------------------------------------------------------------------'
}

--------------------------------------------------

αλλα χανουμε τα arguments των scripts ετσι

οποτε μαλλον να κρατησουμε το προηγουμενο.

Σύνδεση

[INFO] ARCH Linux: Απόψεις, Ερωτήσεις, Σχόλια

Προτεινόμενες αναρτήσεις

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συχνή συμμετοχή στο θέμα

Δημοφιλείς Ημέρες

Συχνή συμμετοχή στο θέμα

Δημοφιλείς Ημέρες

Δημοφιλή Μηνύματα

tr3quart1sta

martinoff

tr3quart1sta

Δημοσιευμένες Εικόνες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Συνδέστε για να σχολιάσετε

Κοινοποίηση σε άλλες σελίδες

Δημιουργήστε ένα λογαριασμό ή συνδεθείτε για να σχολιάσετε

Δημιουργία λογαριασμού

Σύνδεση

Σύνδεση